MoneyWorks

To make it easier to store persistent variables, there are some new functions to facilitate the safe updating of data in the User2 table.

GetMutex/ReleaseMutex can be used to create any number of named mutexes. GetMutex will fail if another client already holds the mutex.

GetMutex (name)

Attempts to obtain a named mutex from the server. If another user already has the named mutex, returns 0, else 1 if successful. Always successful on a single user system.

Use this when you need to ensure that some operation will only be executed by one client.

ReleaseMutex (name)

Releases the named mutex. If client logs out before releasing a mutex, the mutex is automatically released.

Once you have obtained a mutex, it is safe to get, update, and set your persistent data. GetPersistemt and SetPersistent operate specifically on the User2 table, loading an identified record into an associative list (whose keys are the user2 field names)

GetPersistent (devkey, key)

Loads values for a User2 record into an associative array. the array keys are "int1", "int2", "float1", "float2", "date1", "date2", "text1", "text2", "data".

SetPersistent (devkey, key, array)

Updates a user2 record with values from an associative array using the key values as for GetPersistent().

The Update_Currency_Rates sample script in Acme Widgets uses these to keep track of the last time currency rates were updated.

To facilitate scripting the custom report settings UI, and also to allow "library functions" that you can use in a report, there is a new custom control type: Script.

Scripts controls are loaded by the report settings dialog and can get messages associated with the dialog. The script is unloaded automatically when the report finishes.

Handlers declared public are available to expressions in the report using the scriptname:handlername syntax.

By the way, there is also now a Radio control. Contiguous radio controls are automatically grouped.

You can act on changes to checkboxes, popups and radios by implementing an ExitedField handler for the control (no, you cannot ValidateField them).

Note: There is no syntax checking in this dialog. To test your script, write it in the script editor, then copy and paste in here once it is working (in which case the Before should actually be Before:F_REPSETUP)

This is a feature request that has been on the books for a while. Only requested by one user as far as I know.

0003133: User has requested an Item Picking List on the Order screens.
Description: He would like to be able to flag the Items to appear in the Order - from the Item List, and then add the Quantities.

This is the very thing that MWScript is for: functionality that is only wanted by a small percentage of users, which if included in the base product would only add complexity and concomitant fear and confusion for all other users.

It takes a few minutes to write a script to implement this functionality

constant meta = "Sample by Rowan Daniell. http://cognito.co.nz"

// Creates a new Sales Order populated with the highlighted products

property populate = 0

on MakeOrder public      // Invocation point
    let populate = 1    // set one-shot flag
    Navigator("neso")   // make new sales order
end

on Before:F_TRANS:SO(winref)
    if populate // only do our thing when one-shot is set
        let list = GetListHandle(winref, "All Order Lines")
        let row = 0
        foreach prod in product CreateSelection("Product", "**")
            if row > 0  // the first row is inserted automatically
                AddListLine(list)
            endif
            SetListField(list, row, "Item", prod.Code)
            let row = row + 1
        endfor
        let populate = 0
    endif
end

on Load
    // install our command in the Command menu
    InstallMenuCommand("Pick Order for Selection", "Order_From_Sel:MakeOrder")
end